Datei:Fuzzy-alter.svg

Plot der Fuzzy-Funktion Altersbezeichnungen

selbst erstellt

• Gnuplot Quelltext:

set terminal svg
set xrange [0.0:100.0]
set xlabel "Alter"
set output "fuzzy-alter.svg"

set key right bottom
set grid nopolar
set grid xtics nomxtics ytics nomytics noztics nomztics \
 nox2tics nomx2tics noy2tics nomy2tics nocbtics nomcbtics
set grid layerdefault   linetype 0 linewidth 0.25,  linetype 0 linewidth 0.25
s_0(x,a,ep) = 0
s_1(x,a,ep) = 2*((x-a+ep)/(2*ep))**2
s_2(x,a,ep) = 1-(2*((a-x+ep)/(2*ep))**2)
s_3(x,a,ep) = 1
s(x,a,ep)= (x<=a-ep)?         s_0(x,a,ep):  \
           (x > a-ep && x<a)? s_1(x,a,ep):  \
           (x>a && x<a+ep) ?  s_2(x,a,ep):  \
                              s_3(x,a,ep)
unset label

set style line 1 lt rgb "red" lw 2
set style line 2 lt rgb "orange" lw 2
set style line 3 lt rgb "yellow" lw 2
set style line 4 lt rgb "green" lw 2
set style line 5 lt rgb "cyan" lw 2
set style line 6 lt rgb "blue" lw 2
set style line 7 lt rgb "violet" lw 2

plot (1-s(x,30,30))**2 title "sehr jung" ls 1, \
      1-s(x,30,30) title "jung" ls 2, \
      1-((1-s(x,30,30))**2) title "nicht sehr jung" ls 3, \
      sqrt(s(x,60,30)) title "mehr oder weniger alt" ls 4, \
      s(x,60,30) title "alt" ls 5, \
      (s(x,60,30)**2) title "sehr alt" ls 6

Andreas75

9.7.06